<html><head><meta name="color-scheme" content="light dark"></head><body><pre style="word-wrap: break-word; white-space: pre-wrap;">package Test2::Util::Facets2Legacy;
use strict;
use warnings;

our $VERSION = '1.302199';

use Carp qw/croak confess/;
use Scalar::Util qw/blessed/;

use base 'Exporter';
our @EXPORT_OK = qw{
    causes_fail
    diagnostics
    global
    increments_count
    no_display
    sets_plan
    subtest_id
    summary
    terminate
    uuid
};
our %EXPORT_TAGS = ( ALL =&gt; \@EXPORT_OK );

our $CYCLE_DETECT = 0;
sub _get_facet_data {
    my $in = shift;

    if (blessed($in) &amp;&amp; $in-&gt;isa('Test2::Event')) {
        confess "Cycle between Facets2Legacy and $in\-&gt;facet_data() (Did you forget to override the facet_data() method?)"
            if $CYCLE_DETECT;

        local $CYCLE_DETECT = 1;
        return $in-&gt;facet_data;
    }

    return $in if ref($in) eq 'HASH';

    croak "'$in' Does not appear to be either a Test::Event or an EventFacet hashref";
}

sub causes_fail {
    my $facet_data = _get_facet_data(shift @_);

    return 1 if $facet_data-&gt;{errors} &amp;&amp; grep { $_-&gt;{fail} } @{$facet_data-&gt;{errors}};

    if (my $control = $facet_data-&gt;{control}) {
        return 1 if $control-&gt;{halt};
        return 1 if $control-&gt;{terminate};
    }

    return 0 if $facet_data-&gt;{amnesty} &amp;&amp; @{$facet_data-&gt;{amnesty}};
    return 1 if $facet_data-&gt;{assert} &amp;&amp; !$facet_data-&gt;{assert}-&gt;{pass};
    return 0;
}

sub diagnostics {
    my $facet_data = _get_facet_data(shift @_);
    return 1 if $facet_data-&gt;{errors} &amp;&amp; @{$facet_data-&gt;{errors}};
    return 0 unless $facet_data-&gt;{info} &amp;&amp; @{$facet_data-&gt;{info}};
    return (grep { $_-&gt;{debug} } @{$facet_data-&gt;{info}}) ? 1 : 0;
}

sub global {
    my $facet_data = _get_facet_data(shift @_);
    return 0 unless $facet_data-&gt;{control};
    return $facet_data-&gt;{control}-&gt;{global};
}

sub increments_count {
    my $facet_data = _get_facet_data(shift @_);
    return $facet_data-&gt;{assert} ? 1 : 0;
}

sub no_display {
    my $facet_data = _get_facet_data(shift @_);
    return 0 unless $facet_data-&gt;{about};
    return $facet_data-&gt;{about}-&gt;{no_display};
}

sub sets_plan {
    my $facet_data = _get_facet_data(shift @_);
    my $plan = $facet_data-&gt;{plan} or return;
    my @out = ($plan-&gt;{count} || 0);

    if ($plan-&gt;{skip}) {
        push @out =&gt; 'SKIP';
        push @out =&gt; $plan-&gt;{details} if defined $plan-&gt;{details};
    }
    elsif ($plan-&gt;{none}) {
        push @out =&gt; 'NO PLAN'
    }

    return @out;
}

sub subtest_id {
    my $facet_data = _get_facet_data(shift @_);
    return undef unless $facet_data-&gt;{parent};
    return $facet_data-&gt;{parent}-&gt;{hid};
}

sub summary {
    my $facet_data = _get_facet_data(shift @_);
    return '' unless $facet_data-&gt;{about} &amp;&amp; $facet_data-&gt;{about}-&gt;{details};
    return $facet_data-&gt;{about}-&gt;{details};
}

sub terminate {
    my $facet_data = _get_facet_data(shift @_);
    return undef unless $facet_data-&gt;{control};
    return $facet_data-&gt;{control}-&gt;{terminate};
}

sub uuid {
    my $in = shift;

    if ($CYCLE_DETECT) {
        if (blessed($in) &amp;&amp; $in-&gt;isa('Test2::Event')) {
            my $meth = $in-&gt;can('uuid');
            $meth = $in-&gt;can('SUPER::uuid') if $meth == \&amp;uuid;
            my $uuid = $in-&gt;$meth if $meth &amp;&amp; $meth != \&amp;uuid;
            return $uuid if $uuid;
        }

        return undef;
    }

    my $facet_data = _get_facet_data($in);
    return $facet_data-&gt;{about}-&gt;{uuid} if $facet_data-&gt;{about} &amp;&amp; $facet_data-&gt;{about}-&gt;{uuid};

    return undef;
}

1;

=pod

=encoding UTF-8

=head1 NAME

Test2::Util::Facets2Legacy - Convert facet data to the legacy event API.

=head1 DESCRIPTION

This module exports several subroutines from the older event API (see
L&lt;Test2::Event&gt;). These subroutines can be used as methods on any object that
provides a custom C&lt;facet_data()&gt; method. These subroutines can also be used as
functions that take a facet data hashref as arguments.

=head1 SYNOPSIS

=head2 AS METHODS

    package My::Event;

    use Test2::Util::Facets2Legacy ':ALL';

    sub facet_data { return { ... } }

Then to use it:

    my $e = My::Event-&gt;new(...);

    my $causes_fail = $e-&gt;causes_fail;
    my $summary     = $e-&gt;summary;
    ....

=head2 AS FUNCTIONS

    use Test2::Util::Facets2Legacy ':ALL';

    my $f = {
        assert =&gt; { ... },
        info =&gt; [{...}, ...],
        control =&gt; {...},
        ...
    };

    my $causes_fail = causes_fail($f);
    my $summary     = summary($f);

=head1 NOTE ON CYCLES

When used as methods, all these subroutines call C&lt;&lt; $e-&gt;facet_data() &gt;&gt;. The
default C&lt;facet_data()&gt; method in L&lt;Test2::Event&gt; relies on the legacy methods
this module emulates in order to work. As a result of this it is very easy to
create infinite recursion bugs.

These methods have cycle detection and will throw an exception early if a cycle
is detected. C&lt;uuid()&gt; is currently the only subroutine in this library that
has a fallback behavior when cycles are detected.

=head1 EXPORTS

Nothing is exported by default. You must specify which methods to import, or
use the ':ALL' tag.

=over 4

=item $bool = $e-&gt;causes_fail()

=item $bool = causes_fail($f)

Check if the event or facets result in a failing state.

=item $bool = $e-&gt;diagnostics()

=item $bool = diagnostics($f)

Check if the event or facets contain any diagnostics information.

=item $bool = $e-&gt;global()

=item $bool = global($f)

Check if the event or facets need to be globally processed.

=item $bool = $e-&gt;increments_count()

=item $bool = increments_count($f)

Check if the event or facets make an assertion.

=item $bool = $e-&gt;no_display()

=item $bool = no_display($f)

Check if the event or facets should be rendered or hidden.

=item ($max, $directive, $reason) = $e-&gt;sets_plan()

=item ($max, $directive, $reason) = sets_plan($f)

Check if the event or facets set a plan, and return the plan details.

=item $id = $e-&gt;subtest_id()

=item $id = subtest_id($f)

Get the subtest id, if any.

=item $string = $e-&gt;summary()

=item $string = summary($f)

Get the summary of the event or facets hash, if any.

=item $undef_or_int = $e-&gt;terminate()

=item $undef_or_int = terminate($f)

Check if the event or facets should result in process termination, if so the
exit code is returned (which could be 0). undef is returned if no termination
is requested.

=item $uuid = $e-&gt;uuid()

=item $uuid = uuid($f)

Get the UUID of the facets or event.

B&lt;Note:&gt; This will fall back to C&lt;&lt; $e-&gt;SUPER::uuid() &gt;&gt; if a cycle is
detected and an event is used as the argument.

=back

=head1 SOURCE

The source code repository for Test2 can be found at
L&lt;https://github.com/Test-More/test-more/&gt;.

=head1 MAINTAINERS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 AUTHORS

=over 4

=item Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;

=back

=head1 COPYRIGHT

Copyright 2020 Chad Granum E&lt;lt&gt;exodist@cpan.orgE&lt;gt&gt;.

This program is free software; you can redistribute it and/or
modify it under the same terms as Perl itself.

See L&lt;https://dev.perl.org/licenses/&gt;

=cut
</pre></body></html>